module read_data_module
  interface read_data
    module procedure read_integer
    module procedure read_real
  end interface

contains
  subroutine read_real(file_name,raw_data,how_many)
    implicit none
    character (len=*), intent (in) :: file_name
    integer, intent (in) :: how_many
    real, intent (out), dimension (:) :: raw_data
    integer :: i

    open (file=file_name,unit=1)
    do i = 1, how_many
      read (unit=1,fmt=*) raw_data(i)
    end do
  end subroutine read_real
  subroutine read_integer(file_name,raw_data,how_many)
    implicit none
    character (len=*), intent (in) :: file_name
    integer, intent (in) :: how_many
    integer, intent (out), dimension (:) :: raw_data
    integer :: i

    open (file=file_name,unit=1)
    do i = 1, how_many
      read (unit=1,fmt=*) raw_data(i)
    end do
  end subroutine read_integer
end module read_data_module

module sort_data_module
  interface sort_data
    module procedure sort_integer
    module procedure sort_real
  end interface

contains
  subroutine sort_real(raw_data,how_many)
    implicit none
    integer, intent (in) :: how_many
    real, intent (inout), dimension (:) :: raw_data

    call quicksort(1,how_many)
  contains
    recursive subroutine quicksort(l,r)
      implicit none
      integer, intent (in) :: l, r
      integer :: i, j
      real :: v, t

      i = l
      j = r
      v = raw_data(int((l+r)/2))
      do
        do while (raw_data(i)<v)
          i = i + 1
        end do
        do while (v<raw_data(j))
          j= j - 1
        end do
        if (i<=j) then
          t = raw_data(i)
          raw_data(i) = raw_data(j)
          raw_data(j) = t
          i = i + 1
          j = j - 1
        end if
        if (i>j) exit
      end do
      if (l<j) then
        call quicksort(l,j)
      end if
      if (i<r) then
        call quicksort(i,r)
      end if
    end subroutine quicksort
  end subroutine sort_real
  subroutine sort_integer(raw_data,how_many)
    implicit none
    integer, intent (in) :: how_many
    integer, intent (inout), dimension (:) :: raw_data

    call quicksort(1,how_many)
  contains
    recursive subroutine quicksort(l,r)
      implicit none
      integer, intent (in) :: l, r
      integer :: i, j
      integer :: v, t

      i = l
      j = r
      v = raw_data(int((l+r)/2))
      do
        do while (raw_data(i)<v)
          i = i + 1
        end do
        do while (v<raw_data(j))
          j = j - 1
        end do
        if (i<=j) then
          t = raw_data(i)
          raw_data(i) = raw_data(j)
          raw_data(j) = t
          i = i + 1
          j = j - 1
        end if
        if (i>j) exit
      end do
      if (l<j) then
        call quicksort(l,j)
      end if
      if (i<r) then
        call quicksort(i,r)
      end if
    end subroutine quicksort
  end subroutine sort_integer
end module sort_data_module

module print_data_module
  interface print_data
    module procedure print_integer
    module procedure print_real
  end interface

contains
  subroutine print_real(raw_data,how_many)
    implicit none
    integer, intent (in) :: how_many
    real, intent (in), dimension (:) :: raw_data
    integer :: i

    open (file='rsorted.txt',unit=2)
    do i = 1, how_many
      write (unit=2,fmt=*) raw_data(i)
    end do
    close (2)
  end subroutine print_real
  subroutine print_integer(raw_data,how_many)
    implicit none
    integer, intent (in) :: how_many
    integer, intent (in), dimension (:) :: raw_data
    integer :: i

    open (file='isorted.txt',unit=2)
    do i = 1, how_many
      write (unit=2,fmt=*) raw_data(i)
    end do
    close (2)
  end subroutine print_integer
end module print_data_module

program ch2401
use read_data_module
use sort_data_module
use print_data_module
implicit none
integer :: how_many
character (len=20) :: file_name
integer, allocatable, dimension (:) :: integer_data
real, allocatable, dimension (:) :: real_data

  print *, ' How many data items are there?'
  read *, how_many
  print *, ' What is the file name?'
  read '(A)', file_name
  allocate (integer_data(how_many))
  call read_data(file_name,integer_data,how_many)
  call sort_data(integer_data,how_many)
  call print_data(integer_data,how_many)
  print *, ' Phase 1 ends.'
  print *, ' data written to file name isorted.txt'
  deallocate (integer_data)
  print *, ' How many data items are there?'
  read *, how_many
  print *, ' What is the file name?'
  read '(A)', file_name
  allocate (real_data(how_many))
  call read_data(file_name,real_data,how_many)
  call sort_data(real_data,how_many)
  call print_data(real_data,how_many)
  print *, ' program ends.'
  print *, ' data written to file name rsorted.txt'
end program ch2401